Um novo exemplo!

O algoritmo a seguir poderá ser utilizado para verificar se o aluno de um curso superior da UFRN está aprovado por média ou necessitará fazer uma prova de reposição. Para que esse aluno seja aprovado por média, ele deve possuir média igual ou maior que 7, contudo, se esse aluno possuir média igual ou superior a 5 e não tiver nenhuma nota abaixo de 3, ele também estará aprovado.

Se o aluno tiver média igual ou superior a 5, mas qualquer uma das 3 notas que ele obteve durante suas aulas for menor que 3, ele deverá fazer a prova de reposição. Agora, se a média for menor do que 5 e maior ou igual a 3, então ele fará a prova de recuperação. Em último caso, se a média for menor que 3, o aluno não poderá fazer a recuperação e estará reprovado por média.

escreva "Digite a primeira nota:"

var n1 := leia_numero

escreva "Digite a segunda nota:"

var n2 := leia_numero

escreva "Digite a terceira nota:"

var n3 := leia_numero

​

var media := (n1+n2+n3)/3

​

se media >= 7 então

    escreva "Aluno aprovado por média."

senão

    se media >= 5 então

        se n1 >= 3 então

            se n2 >= 3 então

                se n3 >= 3 então

                    escreva "Aluno aprovado."

                senão

                    escreva "Aluno deverá fazer a reposição."

                fim

            senão

                escreva "Aluno deverá fazer a reposição."

            fim

        senão

            escreva "Aluno deverá fazer a reposição."

        fim

    senão

        se media >= 3 então

            escreva "Aluno em recuperação."

        senão

            escreva "Aluno reprovado por média."    

        fim

    fim

fim

​

Você reparou que no algoritmo apresentado há diversos aninhamentos do se...então...senão? Como dito, esses aninhamentos podem ser tanto no bloco da condição verdadeira como no bloco da condição falsa. Nesse mesmo algoritmo, foi possível inserir mais de um nível de aninhamento através do uso de vários se...então...senão, um dentro do outro.

Agora, modifiquei esse algoritmo utilizando o operador lógico '|e|' que você conheceu na aula anterior. Neste exemplo, é analisada a situação do aluno nos mesmos requisitos que o algoritmo apresentado anteriormente. Observe o código seguinte com atenção e perceba que foi diminuída a quantidade de estruturas se...então...senão, de modo a ser obtido um algoritmo mais fácil de ler e entender.

escreva "Digite a primeira nota:"

var n1 := leia_numero

escreva "Digite a segunda nota:"

var n2 := leia_numero

escreva "Digite a terceira nota:"

var n3 := leia_numero

​

var media := (n1+n2+n3)/3

​

se media >= 7 então

    escreva "Aluno aprovado por média."

senão

    se media >= 5 então

        se n1 >= 3 |e| n2 >= 3 |e| n3 >= 3 então

            escreva "Aluno aprovado."

        senão

            escreva "Aluno deverá fazer a reposição."

        fim

    senão

        se media >= 3 então

            escreva "Aluno em recuperação."

        senão

            escreva "Aluno reprovado por média."    

        fim

    fim

fim

​

E aí? Conseguiu perceber que utilizando o operador lógico '|e|' foi possível reescrever o algoritmo com três estruturas de decisão se...então...senão a menos? Apesar disso, os algoritmos de cálculo e de verificação da situação do aluno são equivalentes e, para os mesmos valores de notas n1, n2 e n3, ambos irão gerar as mesmas respostas.

Conheça uma outra forma de escrever algoritmos com a estrutura se...senãose aninhada.

escreva "Digite a primeira nota:"

var n1 := leia_numero

escreva "Digite a segunda nota:"

var n2 := leia_numero

escreva "Digite a terceira nota:"

var n3 := leia_numero

​

var media := (n1+n2+n3)/3

​

se media >= 7 então

    escreva "Aluno aprovado por média."

senãose media >= 5 então

    se n1 >= 3 |e| n2 >= 3 |e| n3 >= 3 então

        escreva "Aluno aprovado."

    senão

        escreva "Aluno deverá fazer a reposição."

    fim

senãose media >= 3 então

    escreva "Aluno em recuperação."

senão

    escreva "Aluno reprovado por média."

fim

​

Nesse exemplo, foi apresentada uma forma diferente de se encadear a estrutura de decisão se...então...senão. Repare que no primeiro comando se, caso a variável media seja menor que 7, é realizado um novo teste com o comando senãose (uma junção dos comandos senão + se). Nessa nova verificação, o teste compara se o valor armazenado em media é maior ou igual a 5.